#version 410

// copied from http://stackoverflow.com/questions/12105330/how-does-this-simple-fxaa-work


// their old names
//uniform sampler2D buf0;
//uniform vec2 frameBufSize;
//varying vec2 texCoords;

// MeLib / Metareal names
uniform sampler2D textureColor;
uniform sampler2D textureDepth;
in vec2 uvV;
uniform vec2 meScreenSize;

out vec4 fragColor;

uniform float time;
uniform float enableFxaa = 1;


void main( void )
{

    vec2 co = gl_FragCoord.xy / vec2(meScreenSize.x, meScreenSize.y);
    gl_FragDepth = texture(textureDepth, co).r;

    if(enableFxaa == 0)
    {
        fragColor.xyz = texture(textureColor,co).xyz;
        fragColor.a = 1.0;
        return;
    }
    
    float FXAA_SPAN_MAX = 8.0;
    float FXAA_REDUCE_MUL = 1.0/8.0;
    float FXAA_REDUCE_MIN = 1.0/128.0;
    
    vec3 rgbNW=texture(textureColor,co+(vec2(-1.0,-1.0)/meScreenSize)).xyz;
    vec3 rgbNE=texture(textureColor,co+(vec2(1.0,-1.0)/meScreenSize)).xyz;
    vec3 rgbSW=texture(textureColor,co+(vec2(-1.0,1.0)/meScreenSize)).xyz;
    vec3 rgbSE=texture(textureColor,co+(vec2(1.0,1.0)/meScreenSize)).xyz;
    vec3 rgbM=texture(textureColor,co).xyz;
    
    vec3 luma=vec3(0.299, 0.587, 0.114);
    float lumaNW = dot(rgbNW, luma);
    float lumaNE = dot(rgbNE, luma);
    float lumaSW = dot(rgbSW, luma);
    float lumaSE = dot(rgbSE, luma);
    float lumaM  = dot(rgbM,  luma);
    
    float lumaMin = min(lumaM, min(min(lumaNW, lumaNE), min(lumaSW, lumaSE)));
    float lumaMax = max(lumaM, max(max(lumaNW, lumaNE), max(lumaSW, lumaSE)));
    
    vec2 dir;
    dir.x = -((lumaNW + lumaNE) - (lumaSW + lumaSE));
    dir.y =  ((lumaNW + lumaSW) - (lumaNE + lumaSE));
    
    float dirReduce = max(
                          (lumaNW + lumaNE + lumaSW + lumaSE) * (0.25 * FXAA_REDUCE_MUL),
                          FXAA_REDUCE_MIN);
    
    float rcpDirMin = 1.0/(min(abs(dir.x), abs(dir.y)) + dirReduce);
    
    dir = min(vec2( FXAA_SPAN_MAX,  FXAA_SPAN_MAX),
              max(vec2(-FXAA_SPAN_MAX, -FXAA_SPAN_MAX),
                  dir * rcpDirMin)) / meScreenSize;
    
    vec3 rgbA = (1.0/2.0) * (
                             texture(textureColor, co.xy + dir * (1.0/3.0 - 0.5)).xyz +
                             texture(textureColor, co.xy + dir * (2.0/3.0 - 0.5)).xyz);
    vec3 rgbB = rgbA * (1.0/2.0) + (1.0/4.0) * (
                                                texture(textureColor, co.xy + dir * (0.0/3.0 - 0.5)).xyz +
                                                texture(textureColor, co.xy + dir * (3.0/3.0 - 0.5)).xyz);
    float lumaB = dot(rgbB, luma);
    
    if((lumaB < lumaMin) || (lumaB > lumaMax))
    {
        fragColor.xyz = rgbA;
    }
    else
    {
        fragColor.xyz = rgbB;
    }
}