#version 410

uniform sampler2D texture1;
in vec2 uvV;

uniform float saturation;
uniform float hueShift;
out vec4 fragColor;


vec3 rgb2hsv(vec3 c)
{
    vec4 K = vec4(0.0, -1.0 / 3.0, 2.0 / 3.0, -1.0);
    vec4 p = mix(vec4(c.bg, K.wz), vec4(c.gb, K.xy), step(c.b, c.g));
    vec4 q = mix(vec4(p.xyw, c.r), vec4(c.r, p.yzx), step(p.x, c.r));
    
    float d = q.x - min(q.w, q.y);
    float e = 1.0e-10;
    return vec3(abs(q.z + (q.w - q.y) / (6.0 * d + e)), d / (q.x + e), q.x);
}

vec3 hsv2rgb(vec3 c)
{
    vec4 K = vec4(1.0, 2.0 / 3.0, 1.0 / 3.0, 3.0);
    vec3 p = abs(fract(c.xxx + K.xyz) * 6.0 - K.www);
    return c.z * mix(K.xxx, clamp(p - K.xxx, 0.0, 1.0), c.y);
}


// Simplest Texture render -- assign "texture1" from varying UV coords.
// Requires vertex shader with uvV output, only.
void main (void)
{
    vec4 rgb = texture(texture1, uvV);
    
    vec3 hsv = rgb2hsv(rgb.rgb);
    hsv.y += saturation;
    hsv.x = mod(hsv.x + hueShift, 1.0);
//    hsv.x = hueShift;
//    hsv.z = 0;
    rgb.rgb = hsv2rgb(hsv);
    rgb.a = 1.0;
    fragColor = rgb;
}